! ANSYS钢筋混凝土整体式模型例子
! Example for smear rebar model in ANSYS
! 作者：陆新征，清华大学土木系
! Author: Lu Xinzheng Dept. Civil Engrg. of Tsinghua University
/PREP7
!*
! 单元属性
ET,1,SOLID65
!*
KEYOPT,1,1,0
KEYOPT,1,5,0
KEYOPT,1,6,0
KEYOPT,1,7,1
!*
!*
!实参数1：未配筋
R,1,2, , , ,2, ,
RMORE, , ,2, , , ,
!*
!实参数2：X方向配筋
R,2,2,.05, , ,2, ,
RMORE, , ,2, , , ,
!*
!*
!材料属性
!混凝土基本材料属性
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,30e9
MPDATA,PRXY,1,,.2
!屈服准则
TB,MISO,1,1,5,
TBTEMP,0
TBPT,,0.0005,15e6
TBPT,,0.001,21e6
TBPT,,0.0015,24e6
TBPT,,0.002,27e6
TBPT,,0.003,24e6
!破坏准则
TB,CONC,1,1,9,
TBTEMP,0
TBDATA,,.5,.9,3e6,30e6,,
TBDATA,,,,1,,,
MPTEMP,,,,,,,,
MPTEMP,1,0
!钢材基本属性
MPDATA,EX,2,,200e9
MPDATA,PRXY,2,,.27
!屈服准则
TB,BISO,2,1,2,
TBTEMP,0
TBDATA,,310e6,2e9,,,,
!建立模型
K,1,,,,
K,2,3,,,
KGEN,2,1,2 ,1 , ,.05, , ,0
KGEN,2,1,2 ,1 , ,0.5, , ,0
A,1,2,4,3
A,3,4,6,5
VEXT,1,2 ,1 ,0,0,.2,,,,
VSEL, , , , 1
VATT, 1, 2, 1, 0
VSEL, , , , 2
VATT, 1, 1, 1, 0
LSEL, all
LESIZE,all,.2, , , , , , ,1
!*
VSEL, all
!*
VMESH,all
!*
/SOLU
!*
ANTYPE,0
!*
!力二范数收敛，2%
CNVTOL,F, ,0.02,2, ,
!*
!加约束
D,3, , , , , ,UY, , , , ,
D,35, , , , , ,UY, , , , ,
D,16, , , , , ,UY, , , , ,
D,48, , , , , ,UY, , , , ,
D,35, , , , , ,ALL, , , , ,
D,48, , , , , ,UZ, , , , ,
!加竖向位移荷载
D,75, ,-0.01, , , ,UY, , , , ,
D,123, ,-0.01, , , ,UY, , , , ,
!加载最少分为20步
NSUBST,20,1000000,20
!输出每步结果
OUTRES,ALL,1
!每步至少迭代25次
CUTCONTROL,NOITERPRED,1

SOLVE

 个人信息 研究工作 实际工程 论文工作 教学工作 资料下载 专题 其他